Открываем новые ордера с помощью функции OrderSend

int  OrderSend(
   string   symbol,              // символ
   int      cmd,                 // торговая операция
   double   volume,              // количество лотов
   double   price,               // цена
   int      slippage,            // проскальзывание
   double   stoploss,            // стоп-лосс
   double   takeprofit,          // тейк-профит
   string   comment=NULL,        // комментарий
   int      magic=0,             // идентификатор
   datetime expiration=0,        // срок истечения ордера
   color    arrow_color=clrNONE  // цвет
   );

//+------------------------------------------------------------------+
//|                                                       Test-1.mq4 |
//|                        Copyright 2019, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
 
#property copyright "Александр Паркер"
#property link      "https://traderblog.net/"
#property version   "1.00"
#property strict
 
//Определяем базовые данные
double StopLoss=30;     //Размер стоп-лосса в пунктах.
double TakeProfit=50;   //Размер тейк-профита в пунктах.
double LotSize=0.05;    //Размер позиции в лотах.
double Slippage=5;      //Допустимое проскальзывание в пунктах.
double Command=OP_BUY;  //Тип ордера. В данном случае ордер на покупку.
 
double CalculateNormalizedDigits()
{
   if(Digits<=3){ return(0.01); } else if(Digits>=4){
      return(0.0001);
   }
   else return(0);
}
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
{
 
   // Рассчитываем цены для стоп-лосса, тейк-профита.
   double nDigits=CalculateNormalizedDigits();
   double OpenPrice=Ask;
   double StopLossPrice=Ask-StopLoss*nDigits;
   double TakeProfitPrice=Ask+TakeProfit*nDigits;
 
   //Определяем переменную для хранения результата работы функции OrderSend()
   int OrderNumber;
   OrderNumber=OrderSend(Symbol(),Command,LotSize,OpenPrice,Slippage,StopLossPrice,TakeProfitPrice);
 
   //Проверяем, исполнился ордер или нет, затем выводим результат.
   if(OrderNumber>0){
      Alert("Ордер ",OrderNumber," открыт");
   }
   else{
      Alert("Ордер не открыт. Ошибка - ",GetLastError());
   }
 
}

OrderSend(Symbol(),OP_BUYSTOP,LotSize,PendingPrice,Slippage,BuyStopLoss, BuyTakeProfit,"Buy Stop Ордер",MagicNumber,0,Green);

OrderSend(Symbol(),OP_BUYLIMIT,LotSize,PendingPrice,Slippage,BuyStopLoss, BuyTakeProfit,"Buy Limit Ордер",MagicNumber,0,Green);

#property copyright     "Александр Паркер"
#property link          "https://traderblog.net/"
#property version       "1.00"
#property strict
#property show_inputs
 
enum Operation{
   buy=OP_BUY,    //BUY
   sell=OP_SELL,   //SELL
};
 
extern double Lots=1;                  //Размер позиции.
extern bool UseRiskPercentage=true;    //Процент риска для расчета размера позиции.
extern double RiskPercentage=2;        //Процент доступного баланса торгового счета для риска.
input Operation Command=buy;           //Тип ордера.
extern int TakeProfit=40;              //Тейк-профит в пунктах.
extern int StopLoss=20;                //Стоп-лосс в пунктах.
extern int Slippage=2;                 //Проскальзывание в пунктах.
extern int MagicNumber=0;              //Магическое число.
extern string Cmt="";                  //Комментарий.
 
//Нормализуем пункты.
double CalculateNormalizedDigits()
{
   if(Digits<=3){
      return(0.01);
   }
   else if(Digits>=4){
      return(0.0001);
   }
   else return(0);
}
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//---
 
   //Если стоп-лосс не установлен и используется процент риска, останавливаем скрипт и выводим требуется стоп-лосс.
   if(StopLoss==0 && UseRiskPercentage){
      Print("Необходим стоп-лосс, если вы используете процент риска.");
      return;
   }
 
   int Cmd=Command;
 
   //Нормализуем и рассчитываем размер позиции.
   double nTickValue=MarketInfo(Symbol(),MODE_TICKVALUE);
   double nDigits=CalculateNormalizedDigits();
   if(Digits==3 || Digits==5){
      Slippage=Slippage*10;
      nTickValue=nTickValue*10;
   }
   if(UseRiskPercentage){
      Lots=(AccountBalance()*RiskPercentage/100)/(StopLoss*nTickValue);
      Lots=MathRound(Lots/MarketInfo(Symbol(),MODE_LOTSTEP))*MarketInfo(Symbol(),MODE_LOTSTEP);
   }
 
   //Установливаем цены открытия, стоп-лосса и тейк-профита
   double OpenPrice=0;
   double TakeProfitPrice=0;
   double StopLossPrice=0;
   if(Cmd==OP_BUY){
      OpenPrice=NormalizeDouble(MarketInfo(Symbol(),MODE_ASK),Digits);
      if(TakeProfit!=0) TakeProfitPrice=NormalizeDouble(OpenPrice+TakeProfit*nDigits,Digits);
      if(StopLoss!=0) StopLossPrice=NormalizeDouble(OpenPrice-StopLoss*nDigits,Digits);
   } 
   if(Cmd==OP_SELL){
      OpenPrice=NormalizeDouble(MarketInfo(Symbol(),MODE_BID),Digits);
      if(TakeProfit!=0) TakeProfitPrice=NormalizeDouble(OpenPrice-TakeProfit*nDigits,Digits);
      if(StopLoss!=0) StopLossPrice=NormalizeDouble(OpenPrice+StopLoss*nDigits,Digits);
   } 
 
   //Выводим всю информацию
   Print("Открываем ордер ",Command," размер ",Lots, " цены открытия ",OpenPrice," проскальзывание ",Slippage," стоп-лосс ",StopLossPrice," тейк-профит ",TakeProfitPrice," комментарий ",Cmt," магическое число ",MagicNumber);
 
   //Отправляем ордер.
   int OrderNumber;
   OrderNumber=OrderSend(Symbol(),Cmd,Lots,OpenPrice,Slippage,StopLossPrice,TakeProfitPrice,Cmt,MagicNumber);
   if(OrderNumber>0){
      Print("Ордер ",OrderNumber," открыт");
   }
   else{
      Print("Ошибка - ",GetLastError());
   }
 
  }